@echo off
goto Top

	......................................................................
	Created 8/7/94 
	Copyright 1994, Larry Leonard.  All rights reserved. 
	CompuServe 71753,2426

	Warranty Disclaimer - Users of RunDoom.Bat must accept this 
	disclaimer of warranty: RunDoom.Bat is supplied "as is".  The author 
	disclaims all warranties, expressed or implied, including, without 
	limitation, the warranties of merchantability and of fitness for any 
	purpose.  The author assumes no liability for damages, direct or 
	consequential, which may result from the use of RunDoom.Bat.

	This program is FREEWARE and may be distributed freely.
 
	DOOM is a trademark of Id Software, inc.
	......................................................................

	......................................................................
	The public domain program ENTER.COM (written by Frank Tracy) should 
	be placed in the same directory as this program. 
	......................................................................
	
	......................................................................
	SmartDrive notes: Very briefly, DOOM wants 4 Meg of RAM, so for best 
	results, set SmartDrive to use all your RAM, less 4 Meg.  Disable 
	all caching for all drives, except read caching on the drive with 
	DOOM.WAD.  Now, before you run a WAD file, copy and then delete it, 
	which loads it in the SmartDrive buffer.  

	IMPORTANT NOTE: If you're not running SmartDrive, comment out all 
			the "smartdrv" commands.  Also, be aware that there
			is a SMARTDRV in your DOS directory *and* in your
			WINDOWS directory.  You should always use the one 
			with the latest date (you may have to modify this
			program, which uses the WINDOWS one).

	IMPORTANT NOTE: The command that copies the WAD file requires that 
			you have enough disk space to do so.  In the case 
			of DOOM.WAD this is about 10 Meg.  If you don't 
			have enough space, you will see the error messages 
			"Insufficient disk space" and "File not found".  
			You may safely ignore these messages.
	......................................................................


rem ......................................................................
rem Check for help-seeking command line arguments.
rem ......................................................................

:Top
if /?==%1 goto Help
if -?==%1 goto Help

rem ......................................................................
rem Prepare SmartDrive.
rem ......................................................................

c:\windows\smartdrv a- b- c  > nul
c:\windows\smartdrv /r  > nul

rem ......................................................................
rem Check for WAD file-loading command line arguments.
rem ......................................................................

set file=%1.wad
if not exist %file% goto Start

set episode=%2
set level=%3
set skill=%4
goto Run

rem ......................................................................
rem The beginning.
rem ......................................................................
:Start
cls
echo  ====================================================
echo  RunDoom v1.0
echo  Copyright 1994 - Larry Leonard - All Rights Reserved
echo  ====================================================

rem ......................................................................
rem Get the WAD file.
rem ......................................................................
echo.
echo    A = Doom
echo    B = Despair
echo    C = DmHQ
echo    D = LiteODay
echo    E = RedRoom
echo    F = TeethUpd
echo    G = HiClimb
echo    H = UAC Dead
echo    I = Apocalypse
echo    J = Abyss
echo    K = ChrisK22
echo    Q =    To Quit
echo.

choice /C:QABCDEFGHIJK /N " Pick a file: "

if errorlevel 12 goto ChrisK22
if errorlevel 11 goto Abyss
if errorlevel 10 goto Apoclpse
if errorlevel  9 goto Uacdead
if errorlevel  8 goto Hiclimb
if errorlevel  7 goto Teethupd
if errorlevel  6 goto Redroom
if errorlevel  5 goto Liteoday
if errorlevel  4 goto Dmhq
if errorlevel  3 goto Despair
if errorlevel  2 goto Doom
if errorlevel  1 goto Quit

rem ......................................................................
rem Get the episode.
rem ......................................................................
:Episode
cls
echo  File %file%.
echo.
echo    1 = Knee-Deep in the Dead
echo    2 = Shores of Hell
echo    3 = Inferno
echo    Q =    To Quit
echo.

choice /C:123Q /N " Pick an Episode: "
echo.

if errorlevel 4 goto Quit
if errorlevel 1 set episode=1
if errorlevel 2 set episode=2
if errorlevel 3 set episode=3

rem ......................................................................
rem Get the level (building).
rem ......................................................................
:Level
cls
echo  File %file%, episode %episode%.
echo.

choice /C:123456789Q " Pick a Level "

if errorlevel 10 goto Quit
if errorlevel  1 set level=1
if errorlevel  2 set level=2
if errorlevel  3 set level=3
if errorlevel  4 set level=4
if errorlevel  5 set level=5
if errorlevel  6 set level=6
if errorlevel  7 set level=7
if errorlevel  8 set level=8
if errorlevel  9 set level=9

rem ......................................................................
rem Get the skill.
rem ......................................................................
:Skill
cls
echo  File %file%, episode %episode%, level %level%.
echo.
echo    1 = I'm too young to die!
echo    2 = Not too rough!
echo    3 = Hurt me plenty!
echo    4 = Ultra-violence!
echo    5 = NIGHTMARE!!!
echo    Q =    To Quit
echo.

choice /C:12345Q /N " Pick a Skill: "

if errorlevel 6 goto Quit       
if errorlevel 1 set skill=1
if errorlevel 2 set skill=2
if errorlevel 3 set skill=3
if errorlevel 4 set skill=4
if errorlevel 5 set skill=5

rem ......................................................................
rem Run DOOM!
rem ......................................................................
:Run
echo.
echo Running file %file%, episode %episode%, level %level%, skill %skill%.
echo.

echo Loading SmartDrive buffer... please stand by...
echo.
copy %file% t$%file% > nul
erase t$%file% > nul

set cmd=doom.exe -devparm -warp %episode% %level% -skill %skill%
if not %file%==DOOM.WAD set cmd=%cmd% -file %file% 

if     exist enter.com  enter.com
if     exist enter.com  %cmd% > ~rundoom.tmp
if not exist enter.com  %cmd%

echo.
echo That was file %file%, episode %episode%, level %level%, skill %skill%.
echo.
pause
goto Start

rem ......................................................................
rem Help.
rem ......................................................................
:Help
echo.
echo  RunDoom command-line syntax:
echo.
echo      RUNDOOM filename episode level skill
echo.
echo  Example:
echo.
echo      RUNDOOM HICLIMB 1 2 4
echo.
goto :Quit

rem ......................................................................
rem Various WAD File Handlers.  Sorted alphabetically for ease-of-use.
rem ......................................................................

:Abyss
set file=ABYSS.WAD
set episode=1
set level=1
goto Skill

:Apoclpse
set file=APOCLPSE.WAD
set episode=1
set level=1
goto Skill

:ChrisK22
set file=CHRISK22.WAD
set episode=2
set level=2
goto Skill

:Despair
set file=DESPAIR.WAD
set episode=2
set level=2
goto Skill

:Dmhq
set file=DMHQ.WAD
set episode=1
set level=1
goto Skill

:Doom
set file=DOOM.WAD
goto Episode

:Hiclimb
set file=HICLIMB.WAD
set episode=1
set level=2
goto Skill

:Liteoday
set file=LITEODAY.WAD
set episode=1
set level=1
goto Skill

:Redroom
set file=REDROOM.WAD
set episode=1
set level=1
goto Skill

:Teethupd
set file=TEETHUPD.WAD
set episode=2
set level=1
goto Skill

:Uacdead
set file=UAC_DEAD.WAD
set episode=1
set level=8
goto Skill

rem ......................................................................
rem Quit Handler.  Note that we reset SmartDrive to what it was before we
rem started.
rem ......................................................................
:Quit
set file=
set episode=
set level=
set skill=
set cmd=
c:\windows\smartdrv a+ b+ c+ > nul
echo.

rem ......................................................................
rem End of File
rem ......................................................................