@ECHO OFF
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++
ECHO +                                                  +
ECHO + You must run this batch file from within your    +
ECHO + Wolfenstein directory.  The following files      +
ECHO + must also be present:                            +
ECHO +                                                  +
ECHO +  * NEWMAPS                                       +
ECHO +  * OLDMAPS                                       +
ECHO +  * MODHEAD.WL6                                   +
ECHO +  * MODMAPS.WL6                                   +
ECHO +  * OLD.WL6                                       +
ECHO +                                                  +
ECHO +  This batch file will make backup copies of      +
ECHO +  your original Wolfenstein map files and also    +
ECHO +  create batch files to select which maps to use  +
ECHO +                                                  +
ECHO +      ** 200k free disk space is required **      +
ECHO +                                                  +
ECHO + Press any key to begin installation or CNTRL-C   +
ECHO + to abort...                                      +
ECHO +                                                  +
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++
PAUSE
CLS
IF EXIST MAPHEAD.WL6 GOTO 1THERE
GOTO ERR
:1THERE
IF EXIST GAMEMAPS.WL6 GOTO 2THERE
:ERR
ECHO ERROR - Files MAPHEAD.WL6 and/or GAMEMAPS.WL6 not found...
ECHO         Install must be run in your Wolfenstein directory
ECHO         and only works with the registered game.
GOTO END
:2THERE
IF EXIST ORIGHEAD.WL6 GOTO ERR0
IF EXIST ORIGMAPS.WL6 GOTO ERR0
GOTO COPYEM
:ERR0
ECHO ERROR - Files ORIGHEAD.WL6 and/or ORIGMAPS.WL6 already present!
ECHO         Please move or delete these files to install.
GOTO END
:COPYEM
COPY MAPHEAD.WL6 ORIGHEAD.WL6
COPY GAMEMAPS.WL6 ORIGMAPS.WL6
IF EXIST ORIGHEAD.WL6 GOTO 1OK
GOTO ERR1
:1OK
IF EXIST ORIGMAPS.WL6 GOTO 2OK
:ERR1
ECHO ERROR - Unable to find files ORIGHEAD.WL6 and/or ORIGMAPS.WL6!
ECHO         Additional disk space may be necessary to install.
DEL ORIGHEAD.WL6
GOTO END
:2OK
IF EXIST NEW.WL6 GOTO REMOVE
GOTO SETUP
:REMOVE
DEL NEW.WL6
:SETUP
RENAME NEWMAPS NEWMAPS.BAT
RENAME OLDMAPS OLDMAPS.BAT
COPY MODHEAD.WL6 MAPHEAD.WL6
COPY MODMAPS.WL6 GAMEMAPS.WL6
RENAME OLD.WL6 NEW.WL6
ECHO ***********************************************
ECHO ***********************************************
ECHO **                                           **
ECHO **  New map files successfully installed!    **
ECHO **  To use new maps, run batch file NEWMAPS  **
ECHO **  To use old maps, run batch file OLDMAPS  **
ECHO **                                           **
ECHO ***********************************************
ECHO ***********************************************
:END
@ECHO ON